; PWG ISTO 5100.1 ABNF DEFINITIONS
;
; Last Update: March 29, 2022
;
; This document contains the current ABNF definitions for the IPP Finishings
; v3.0 Specification, PWG ISTO Document Number 5100.1.
;
; The ABNF definitions contained herein, if different from the definitions in
; the specification, supercede those present in the specification.
;
; NOTE: This ABNF allows for a mix of uppercase and lowercase letters in
; names, however specific bindings such as the Internet Printing Protocol
; only allow for lowercase letters.
;

;;;; Figure 6 - ABNF for "printer-finisher" Values

printer-finisher = 1*finisher-required *finisher-optional
    ; set of finisher elements encoded into one value 
finisher-required = finisher-req ";"
finisher-req = finisher-type / finisher-unit /
                 finisher-max-capacity / finisher-index /
                 finisher-presentonoff / finisher-status
finisher-optional = finisher-opt ";"
finisher-opt = finisher-capacity
    
finisher-type = "type" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g.,
    ; 'stitcher') of finDeviceType [RFC3806] mapped
    ; indirectly from the *label* in FinDeviceTypeTC

finisher-unit = "unit" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g., 'other') of
    ; finDeviceCapacityUnit in [RFC3806] mapped indirectly from
    ; the *label* in PrtCapacityUnitTC [RFC3805]

finisher-max-capacity = "maxcapacity" "=" 1*[DIGIT / "-"]
    ; integer value as a numeric string mapped directly from
    ; finDeviceMaxCapacity [RFC3806]

finisher-capacity = "capacity" "=" 1*[DIGIT / "-"]
    ; integer value as a numeric string mapped directly from
    ; finDeviceCurrentCapacity [RFC3806]

finisher-index = "index" "=" 1*DIGIT
    ; integer value as a numeric string mapped directly from
    ; finDeviceIndex [RFC3806]

finisher-presentonoff = "presentonoff" "=" "other"/ "on" /
                                           "off" / "notPresent"
    ; string value as an alpha string of
    ; finDevicePresentOnOff [RFC3806] mapped indirectly
    ; from the *label* in PresentOnOff [RFC3805]

finisher-status = "status" "=" 1*DIGIT
    ; integer value as a numeric string mapped directly from
    ; finDeviceStatus [RFC3806]

finisher-ext      = finisher-extname "=" finisher-extvalue
finisher-extname  = 1*[ALPHA / DIGIT / "-"]
finisher-extvalue = 1*[ALPHA / DIGIT / "-" / "." / ","]
    ; extension point for other MIB values not mapped


;;;; Figure 3 - ABNF for "printer-output-tray" Values

printer-output-tray = *output-required *[output-optional]
    ; set of output elements encoded into one value

output-required     = output-req ";"
output-req          = output-type /
                      output-max-capacity /
                      output-page-delivery /
                      output-remaining /
                      output-stacking-order /
                      output-status /
                      output-name

output-optional     = output-opt ";"
output-opt          = output-index /
                      output-unit /
                      output-offset-stacking

output-type         = "type" "=" 1*ALPHA
    ; enumerated value as an alpha string
    ; (e.g., 'removableBin') of prtOutputType
    ; in [RFC3805] mapped indirectly from
    ; the *label* in PrtOutputTypeTC in [IANAPRT]

output-max-capacity = "maxcapacity" "=" 1*[DIGIT / "-"]
    ; integer value as a numeric string mapped directly from
    ; prtOutputMaxCapacity in [RFC3805]

output-remaining    = "remaining" "=" 1*[DIGIT / "-"]
    ; integer value as a numeric string mapped directly from
    ; prtOutputRemainingCapacity in [RFC3805]

output-status       = "status" "=" 1*DIGIT
    ; integer value as a numeric string mapped directly from
    ; prtOutputStatus in [RFC3805]

output-name         = "name" "=" 1*ALPHA
    ; string value as an alpha string mapped directly from
    ; prtOutputName in [RFC3805]

output-index        = "index" "=" 1*DIGIT
    ; integer value as a numeric string mapped directly from
    ; prtOutputIndex in [RFC3805]

output-unit         = "unit" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g., 'other') of
    ; prtOutputCapacityUnit in [RFC3805] mapped indirectly from
    ; the *label* in PrtCapacityUnitTC in [RFC3805]

output-stacking-order = "stackingorder" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g., 'firstToLast') of
    ; prtOutputStackingOrder in [RFC3805] mapped indirectly from
    ; the *label* in PrtOutputStackingOrderTC in [RFC3805]

output-page-delivery = "pagedelivery" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g., 'faceUp') of
    ; prtOutputPageDeliveryOrientation in [RFC3805] mapped indirectly
    ; from the *label* in PrtOutputPageDeliveryOrientationTC in
    ; [RFC3805]

output-offset-stacking = "offsetstacking" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g., 'notPresent') of
    ; prtOutputOffsetStacking in [RFC3805] mapped indirectly from
    ; the *label* in PresentOnOff in [RFC3805]


;;;; Figure 9 - ABNF for "printer-finisher-supplies" Values

finisher-supply = 1*supply-required *supply-optional
    ; set of finisher supply elements encoded into one value 
supply-required = supply-req ";"
supply-req = supply-class / supply-type / supply-description /
             supply-unit / supply-max / supply-current-level /
             supply-color

supply-optional = supply-opt ";"
supply-opt = supply-index / supply-device-index / supply-ext

supply-class = "class" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g., 'supplyThatIsConsumed')
    ; of prtMarkerSuppliesClass in [RFC3805] mapped indirectly from
    ; the *label* in PrtMarkerSuppliesClassTC in [RFC3805]

supply-type = "type" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g., 'staples') of
    ; prtMarkerSuppliesType in [RFC3805] mapped indirectly from
    ; the *label* in PrtMarkerSuppliesTypeTC in [RFC3805]

supply-unit = "unit" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g., 'items' or 'percent')
    ; of finSupplyUnit in [RFC3806] mapped indirectly from the *label*
    ; in PrtMarkerSuppliesSupplyUnitTC in [RFC3805]

supply-max = "max" "=" 1*[DIGIT / "-"]
    ; integer value as a numeric string mapped directly from
    ; finSupplyMaxCapacity in [RFC3806]

supply-current-level = "level" "=" 1*[DIGIT / "-"]
    ; integer value as a numeric string mapped directly from
    ; finSupplyCurrentLevel in [RFC3806]

supply-color = "color" "=" 1*ALPHA
    ; enumerated value as an alpha string (e.g., 'silver') of
    ; finSupplyColorName in [RFC3806] mapped indirectly from the color
    ; names from PWG Media Standardized Names 2.0 [PWG5101.1]

supply-index = "index" "=" 1*DIGIT
    ; integer value as a numeric string mapped directly from
    ; finSupplyIndex in [RFC3806]

supply-device-index = "deviceIndex" "=" 1*ALPHA
    ; string value as an alpha string mapped directly from
    ; finSupplyDeviceIndex in [RFC3806]

supply-ext      = supply-extname "=" supply-extvalue
supply-extname  = 1*[ALPHA / DIGIT / "-"]
supply-extvalue = 1*[ALPHA / DIGIT / "-" / "." / ","]
    ; extension point for other MIB values not mapped