Appendix B - IEEE 1284 Command Set Format (Normative)

Conforming implementations of the Printer Port Monitor MIB SHOULD construct values of the COMMAND SET (CMD) capability in the 'ppmPrinterIEEE1284DeviceId' object according to the following ABNF [RFC5234], for interoperability and user-friendly behavior.

Conforming implementations of this Command Set format MUST choose a registered IANA Printer MIB Interpreter Type (e.g., 'PS' or 'PCL'), when available, rather than the equivalent registered or vendor MIME Media Type, for interoperability.

Note: Searching for embedded forward slash '/' will distinguish MIME Media Types (present) from IANA Printer MIB Interpreter Types (absent).

;
; ABNF for IEEE 1284 Device ID Command Set
;
command-set         = command-key ":" command-langs ";"
    ; IEEE 1284 command languages concatenated into one capability

command-key         = "COMMAND SET" / "CMD"
    ; IEEE 1284 command set keyword or abbreviation

command-langs       = command-lang *[ "," command-lang]
    ; IEEE 1284 command languages

command-lang        = interpreter-type / mime-media-type
    ; IEEE 1284 command language (job control or page description)

interpreter-type    = 1-59interpreter-chars
    ; Label from PrtInterpreterLangFamilyTC [IANA-PRT]
    ; with deleted 'lang' prefix (e.g., 'PS' or 'PCL')

interpreter-chars   = ALPHA / DIGIT
    ; Alphanumeric with no punctuation

mime-media-type     = type-name "/" subtype-name
    ; IANA Media Type [IANA-MIME] (e.g., 'text/plain') or
    ; Vendor Media Type (e.g., 'application/vnd.hp-PCL')

;
; ABNF for MIME Media Types quoted from page 7 of [RFC4288]
;
type-name           = reg-name
subtype-name        = reg-name

reg-name            = 1*127reg-name-chars
reg-name-chars      = ALPHA / DIGIT / "!" /
                      "#" / "$" / "&" / "." /
                      "+" / "-" / "^" / "_"

Normative References

[IANA-MIME]
    IANA Media Types Registry per [RFC4288]
    ftp://ftp.iana.org/assignments/media-type

[IANA-PRT]
    IANA Printer MIB (originally published in RFC 3805, June 2004).
    ftp://ftp.iana.org/assignments/ianaprinter-mib

[RFC4288]
    IETF Media Type Specifications and Registration Procedures,
    RFC 4288, December 2005.
    http://www.ietf.org/rfc/rfc4288.txt

[RFC5234]
    IETF Augmented BNF for Syntax Specifications: ABNF,
    RFC 5234, January 2008.
    http://www.ietf.org/rfc/rfc5234.txt